home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS069.dsk / SURVIVE.bas < prev    next >
BASIC Source File  |  2012-02-16  |  5KB  |  111 lines
  1. 10  HOME : REM  U.F.O   CREATIVE COMPUTING JUL/AUG 77
  2. 15  PRINT " "
  3. 20  PRINT "SURVIVE"
  4. 25  PRINT " "
  5. 30  PRINT "BY REYMOND J KERNAY"
  6. 35  PRINT "FM PG 141 OF J/A 77 CREATIVE COMPUTING"
  7. 37  PRINT "LISTED BY DAVID AMES"
  8. 40  PRINT " "
  9. 50  PRINT "THE WORLD WAS DESTROYED BY UFO'S.  YOU  ARE ONLY ONE LEFT.  THERE IS ALSO ONLY  ONE OF THEM LEFT.  CAN YOU SURVIVE?"
  10. 55  PRINT " "
  11. 90  INPUT "DO YOU WANT INSTRUCTIONS ? ";A$
  12. 100  IF A$ = "Y"  OR A$ = "YES"  THEN  GOTO 5000
  13. 110  GOSUB 6000
  14. 120  INPUT "THIS IS COMPUTER CONTROL WHO ARE YOU ?    ";A$
  15. 490  PRINT "GOOD LUCK ";A$
  16. 500 P = 10000:P(1) = 10000:A =  RND(1) *200000
  17. 510  PRINT "LEAVING ORBIT ";A$: PRINT "SHIP APPROACHING AT ";A;" MILES"
  18. 520  PRINT "WHAT ARE YOUR ORDERS ";A$;: INPUT C
  19. 525  PRINT : PRINT : PRINT 
  20. 530 Q =  INT( RND(1) *2) +1: IF C <1  THEN 520
  21. 540  ON C GOTO 570,650,710,750,780,820
  22. 560  PRINT "LETS NOT CRACK UNDER PRESURE": GOTO 520
  23. 570  IF A >11005  THEN 560
  24. 580 P = P -10: PRINT "GUNS FIRED"
  25. 590  FOR X = 1 TO A *2  STEP 1000
  26. 600 O =  PEEK( -16336): NEXT X
  27. 610  IF Q = 1  THEN 630
  28. 620  PRINT "MISSED": GOTO 830
  29. 630  PRINT " HIT "
  30. 640 P(1) = P(1) -100: GOTO 830
  31. 650  IF A >100000  OR A <10000  THEN 560
  32. 660 P = P -100: PRINT "WARHEAD LAUNCHED"
  33. 670  FOR X = 1 TO A *2  STEP 35000:O =  PEEK( -16336) + PEEK( -16336): NEXT X
  34. 680  IF Q = 1  THEN 700
  35. 690  PRINT "MISSED": GOTO 830
  36. 700  PRINT " HIT  ":P(1) = P(1) -1000: GOTO 830
  37. 710  IF A <100000  THEN 560
  38. 715 P = P -1000: PRINT "LAZAR FIRED <CTRL-G><CTRL-G>"
  39. 720  IF Q = 1  THEN 730
  40. 725  PRINT "MISSED": GOTO 830
  41. 730  PRINT " HIT "
  42. 740 P(1) = P(1) -3000: GOTO 830
  43. 750 B =  RND(1) *40000 +10000:A = A -B:P = P -100: IF A <1  THEN 770
  44. 760  GOTO 830
  45. 770  INVERSE : PRINT "COLLISION": PRINT "BOTH SHIPS DESTROYED": NORMAL : GOTO 1080
  46. 780 B =  RND(1) *40000 +10000:A = A +B:P = P -100: IF A >200050  THEN 800
  47. 790  GOTO 830
  48. 800  PRINT A$;" WE CAN NOT RUN AWAY": PRINT "RANGE NOW IS 200000 ":A = 200000: GOTO 830
  49. 820 P = P +100
  50. 830  PRINT "ENEMY: RANGE= ";A: PRINT  TAB( 7);"POWER = ";P(1)
  51. 840  IF P(1) <1  THEN 1110
  52. 850  IF P(1) <500  THEN 1040
  53. 860  IF A <5000  THEN 1070
  54. 870 R =  INT( RND(1) *3) +1:Q =  INT( RND(1) *2) +1
  55. 880  IF R = 1  THEN 970
  56. 885  IF R = 2  THEN 920
  57. 890  IF A <100000  THEN 870
  58. 895 P(1) = P(1) -1000: PRINT "ENEMY FIRES LAZAR"
  59. 900  IF Q = 1  THEN 910
  60. 905  PRINT "MISSED": GOTO 1010
  61. 910  PRINT "WE ARE HIT":P = P -3000: GOTO 1010
  62. 920  IF A >100000  OR A <10000  THEN 870
  63. 930 P(1) = P(1) -100: PRINT "ENEMY WARHEAD FIRED"
  64. 940  FOR D = 1 TO A  STEP 35000:O =  PEEK( -16336) + PEEK( -16336): NEXT D
  65. 950  IF Q = 1  THEN 960
  66. 955  PRINT "MISSED": GOTO 1010
  67. 960 P = P -1000: PRINT "WE ARE HIT ": GOTO 1010
  68. 970  IF A >11000  THEN 870
  69. 975 P(1) = P(1) -10: PRINT "ENEMY FIRES SHELL"
  70. 980  FOR D = 1 TO A  STEP 1000:O =  PEEK( -16336): NEXT D
  71. 990  IF Q = 1  THEN 1000
  72. 995  PRINT "MISSED": GOTO 1010
  73. 1000  PRINT "WE ARE HIT":P = P -100
  74. 1010  PRINT : PRINT "STATUS SHIP: RANGE: ";A: PRINT  TAB( 14);"POWER: ";P: IF P <1  THEN 1130
  75. 1030  GOTO 520
  76. 1040 P(1) = P(1) +100: PRINT "ENEMY RESTING": GOTO 1010
  77. 1050 B =  RND(1) *40000 +10000:A = A -B: PRINT "ENEMY APPROCHING ";A$
  78. 1060  GOTO 1010
  79. 1070 B =  RND(1) *40000 +10000:A = A +B: PRINT "ENEMY RETREATING": GOTO 1010
  80. 1080  PRINT : PRINT "THAT WAS DUMB";A$: GOTO 1140
  81. 1110  PRINT : PRINT "ENEMY GONE  NO POWER!": GOTO 1210
  82. 1130  PRINT : PRINT "NO POWER  ENEMY VICTOR "
  83. 1140  REM  
  84. 1150  REM 
  85. 1210  END 
  86. 4999  END 
  87. 5000  SPEED= 140: HOME : VTAB 24
  88. 5010  PRINT "YOU ARE ABOUT TO RECIEVE HIGH SECURITY": PRINT "INFORMATION PLEASE EAT ANY HARD COPIES": PRINT "AFTER READING"
  89. 5020  PRINT : PRINT : PRINT "THIS IS THE YEAR 2080"
  90. 5030  PRINT "CIVILIZATION AS YOU KNOW IT HAS BEEN": PRINT "DESTROYED    NATIONS HAVE BEEN REDUCED": PRINT "TO RUBBLE IN A MASSIVE SPACE WAR"
  91. 5040  PRINT : PRINT "YOU ARE ON A SPACE SHIP WHOSE SOLE ": PRINT "PURPOSE IS TO SAFE GUARD THE 150 PEOPLE": PRINT "ON YOUR SHIP  THE SOLE SURVIVORS "
  92. 5050  PRINT : PRINT "YOUR MISSION: FIND A PLANET SUITABLE ": PRINT "FOR YOUR COLONISTS ": INVERSE : PRINT "PROBLEM";: NORMAL : PRINT "  THE ENEMY STILL EXIST !"
  93. 5060  PRINT : PRINT "BY THE TIME YOU READ THIS THE EARTH": PRINT "WILL NO LONGER EXIST"
  94. 5070  PRINT : PRINT : PRINT "THE ENEMY HAS THE SAME CAPABILITIES": PRINT "AS YOU DO   EACH HIT DRAINS THE VICTUM": PRINT "BY (SPENT TO SHOOT)*10 EXCEPT LAZER": PRINT "(SPENT)*3"
  95. 5080  PRINT "BOTH ARE ON THE SAME MISSION ON EQUAL": PRINT "TERMS  (WE GOT THEM EXCEPT FOR ONE)": PRINT "YOU MUST GET HIM BEFORE HE GETS YOU": PRINT 
  96. 5090  PRINT "THIS MESSAGE WAS RECORDED  ": PRINT "EARTH IS DEAD!!!"
  97. 5100  FOR I = 1 TO 24
  98. 5110  FOR A = 1 TO 500
  99. 5120  NEXT A
  100. 5130  PRINT : NEXT I
  101. 5140  SPEED= 255
  102. 5150  GOTO 110
  103. 6000  HOME : PRINT  TAB( 16);: PRINT "WEAPONTRY": PRINT 
  104. 6010  PRINT "TYPE"; TAB( 9);"DESCRIP"; TAB( 20);"RANGE"; TAB( 33);"FUEL": PRINT 
  105. 6020  PRINT "  1"; TAB( 7);"HEAVY GUNS"; TAB( 24);"0-11000"; TAB( 33);"  10"
  106. 6030  PRINT "  2"; TAB( 7);"WARHEADS"; TAB( 20);"10000-100000"; TAB( 33);" 100"
  107. 6040  PRINT "  3"; TAB( 7);"LAZER"; TAB( 19);"100000-200000"; TAB( 33);"1000"
  108. 6050  PRINT "  4"; TAB( 7);"APPROACH"; TAB( 33);" 100"
  109. 6060  PRINT "  5"; TAB( 7);"RETREAT"; TAB( 33);" 100"
  110. 6070  PRINT "  6"; TAB( 7);"PASS"; TAB( 13);"NO MOVE GAIN 100 FUEL UNITS"
  111. 6080  POKE 34,11: HOME : PRINT "NAX SPEED = 50000 MILES": PRINT "SPEEDS VARY  10000-50000": PRINT "WARDEADS SPEED =35000  SHELLS =1000": PRINT : PRINT "GOOD LUCK ": RETURN